#
#
#
# get_db_info_data_util.cfv
#
#
#

include "templates.util.encoding";
include "templates.util.log_format_util";

# 
#
#
# get_db_info_log_format_item_dat()
#
#
#

subroutine(get_db_info_log_format_item_dat(
	string log_format_name), (
	
	# This returns a javascript array where the first item
	# is the main log format label. Any subsequent items are added
	# from the log format info node, if any.

	debug_message("#### get_db_info_log_format_item_dat()\n");
	debug_message("#### log_format_name: " . log_format_name . "\n");
	
	string log_format_item_dat = "{";
	string main_label;
	
	if (?("log_formats." . log_format_name)) then (
	
		# debug_message("#### log_format_name exists in log_formats \n");
	
		#
		# Add the main log format label
		#
		
		node log_format = "log_formats." . log_format_name;
		bool add_device_name_labels = false; # Only true for manual log format list
		node log_format_info_labels = get_log_format_labels_from_log_format_info(log_format, add_device_name_labels);
			
		if (?(log_format . ".log.format.format_label") and @(log_format . ".log.format.format_label") ne "") then (
			main_label = @(log_format . ".log.format.format_label");
		)
		else (
			main_label = log_format_name;
		);
		
		
		#
		# Add labels from log format info, if any
		#
		
		
		if (num_subnodes(log_format_info_labels) > 0) then (
			
			node item;
			string label;
			string info_labels_dat = "[";
			int number_info_labels = 0;
			
			foreach item log_format_info_labels (
			
				label = @item;
				
				if (label ne main_label) then (
				
					info_labels_dat .= '"' . encode_json(label) . '",';
					number_info_labels++;
				);
			);
			
			if (number_info_labels > 0) then (
			
				info_labels_dat = replace_last(info_labels_dat, ",", "]");
				log_format_item_dat .= add_json("infoLabels", info_labels_dat, "obj");
			);
		);
	)
	else (
		
		# The log_format with log_format_name does not exist, use the name
		
		# debug_message("#### log_format_name DOES NOT EXIST in log_formats \n");
		
		if (log_format_name eq "") then (
			log_format_name = "(Unknown)";
		);
		
		main_label = log_format_name;
	);
	
	log_format_item_dat .= add_json("label", main_label, "string");
	log_format_item_dat = close_json(log_format_item_dat);
	
	# return
	log_format_item_dat;
));