{=
	#
	#
	# dev.cfv (This template will be modified so that it shows links for miscellaneous developer tools)
	#
	# This template is used for debugging purposes only. It shows all option_info shortcuts
	# at a glance, collected from option_info. It checks for duplicate shortcuts, empty labels and descriptions.
	# 
	# 
	
	
	include "docs.english.util"; # KHP-RC, "docs.util" should work as well but it does not!
	
	include "templates.util.base_util";
	include "templates.util.encoding";
	
	include "templates.util.html";
	include "templates.util.linked_files.linked_files_util";
	
	debug_message("\n\n#### dev.cfv START \n");

	#
	# 
	# Track all shortcuts in "v.temp_debug.shortcuts", i.e.:
	# v.temp_debug.shortcuts.rn = 1
	# v.temp_debug.shortcuts.p = 1
	# v.temp_debug.shortcuts.f = 2 --> The number indicates of how often a specific shortcut occurs, that's how we check for duplicates
	#
	#
	
	#
	# Only allow root_admin access
	#
	
	bool is_root_admin = get_is_root_admin();
	
	if (is_root_admin) then (
	
		delete_node("v.temp_debug");
		v.temp_debug.shortcuts = "";
		v.temp_debug.number_of_options = 0;
		
		
		subroutine(build_header_row, (
		
			'<tr>\n';
			'<th>Shortcut</th>';
			'<th>Name</th>';
			'<th>Type</th>';
			'<th>Label</th>';
			# '<th>Path</th>';
			'<th>Description</th>';
			'</tr>\n';
		
		));
		
		
		subroutine(handle_shortcut(
			string shortcut), (
			
			int count = 1;
			
			if (?("v.temp_debug.shortcuts." . shortcut)) then (
				# shortcut already exists
				
				count = @("v.temp_debug.shortcuts." . shortcut) + 1;
			);
			
			"v.temp_debug.shortcuts." . shortcut = count;
		));
		
		subroutine(handle_option(
			node the_option), (
			
			debug_message("\n\n#### handle_option() START \n");
			
			debug_message("#### the_option : " . node_as_string(the_option) . "\n");
			
			int option_number = @("v.temp_debug.number_of_options") + 1;
			v.temp_debug.number_of_options = option_number;
	
			string option_path = the_option;
			string option_name = node_name(the_option);
			string option_type;
			string shortcut;
			string lang_options_path = replace_first(option_path, "option_info.", "lang_options.");
			string option_label;
			string short_description;
			string long_description;
			string description;
			
			node item;
			string item_name;
			bool item_has_subnodes = false;
			
			# Note, if one item of the option node has subnodes we indicate
			# that the item has subitems which are displayed in separate table
			# below the current group
			
			foreach item the_option (
			
				if (num_subnodes(item) == 0) then (
				
					item_name = node_name(item);
					
					if (item_name eq "type") then (
					
						option_type = @item;
					)
					else if (item_name eq "shortcut") then (
					
						shortcut = @item;
				
						if (shortcut ne "") then (
						
							handle_shortcut(shortcut);
							shortcut = "-" . shortcut;
						);
					);
				)
				else (
				
					item_has_subnodes = true;
				);		
			);
			
			if (item_has_subnodes) then (
			
				option_name .= '<br /><div class="subitems-info">(Item is a group of other items, see next table)</div>';
			);
			
			
			# Handle language variables
			
			if (?(lang_options_path)) then (
			
				if (?(lang_options_path . ".label")) then (
					option_label = @(lang_options_path . ".label");
				);
				
			
				if (?(lang_options_path . ".short_description")) then (
					short_description = @(lang_options_path . ".short_description");
				);
				
				if (?(lang_options_path . ".long_description")) then (
					long_description = expand(@(lang_options_path . ".long_description"));
				);
				
				
				if (short_description ne "" or long_description ne "") then (
					# description = "<em>Short</em><br />" . string_to_html(short_description) . "<br /><br /><em>Long</em><br />" . string_to_html(long_description);
					description = "<em>Short</em><br />" . string_to_html(short_description) . "<br /><br /><em>Long</em><br />" . long_description;
				);
			);
			
			'<tr>\n';
			'<td>' . shortcut . '</td>';
			'<td>' . option_name . '</td>';
			'<td>' . option_type . '</td>';
			'<td>' . option_label . '</td>';
			'<td class="description"><div style="display:block">' . description . '</div></td>';
			'</tr>\n';
		));
		
		
		subroutine(build_options_group(
			node the_group), (
			
			string group_label = replace_first(the_group, "option_info.", "");
			
			if (contains(group_label, ".")) then (
			
				group_label = replace_all(group_label, ".", " &gt ");
			);
			
			'<h2>' . group_label . '</h2>';
			
			'<table cellspacing="0">';
			
			build_header_row();
			
			node group_item;
			
			foreach group_item the_group (
			
				handle_option(group_item);
			);
			
			'</table>';
			
			
			# If the_group contains a shortcut node there must be some mismatch
			
			if (the_group?{"shortcut"}) then (
				string shortcut = @the_group{"shortcut"};
				'<div class="error">';
				'There must be some mismatch in above group because it contains a shortcut node!<br />';
				'Shortcut: ' . shortcut . '<br />';
				'</div>';
				
				handle_shortcut(shortcut);
			);
			
			#
			#
			# It is possible that a subitem of this group contains another group, however, we
			# need to start a new group, hence we do it here!
			#
			#
			
			node subitem;
			bool is_subitem_group;
			
			foreach group_item the_group (
			
				is_subitem_group = false;
			
				foreach subitem group_item (
				
					if (num_subnodes(subitem) > 0) then (
					
						# debug_message("\n#### K group_item: " . group_item . "\n");
						# debug_message("#### K subitem: " . subitem . "\n\n");
					
						# This item must be another group
						is_subitem_group = true;
						last;
					);
				);
				
				if (is_subitem_group) then (
					build_options_group(group_item);
				);
			);
		));
		
		
		
		subroutine(collect_options(
			node the_options), (
			
			node item;
			node subitem;
			
			foreach item the_options (
			
				# Check if we are at a node which is the group node for one or more options
				
				node first_subnode = subnode_by_number(item, 0);
				bool is_options_group_node = true;
				
				foreach subitem first_subnode (
				
					if (num_subnodes(subitem) > 0) then (
						is_options_group_node = false;
						last;
					);
				);
				
				
				if (is_options_group_node) then (
				
					build_options_group(item);
				
				)
				else (
				
					collect_options(item);
				);
			);
			
		));			
		
		set_doctype();
		'<html>\n';
		'<head>\n';
		'<title>Developer Tools</title>\n';
		set_meta_content();
		
		#
		#
		# css files
		#
		#
		
		node misc_file_map = "templates.util.linked_files.file_maps.misc_file_map";
		
		add_css_files(misc_file_map, "dev");
		
		'</head>\n';
		'<body>\n';
		
		'<h1>Option Info Summary</h1>';
		
		
		
		string html = collect_options("option_info" );
	
		node debug = "v.temp_debug";
		
		debug_message("\n" . node_as_string(debug) . "\n");
	
		node debug_shortcuts = debug{"shortcuts"};
		int number_of_options = @debug{"number_of_options"};
		int number_of_shortcuts = num_subnodes(debug_shortcuts);
		int number_of_duplicate_shortcuts = 0;
		string duplicate_shortcuts;
		
		# Check for duplicate shortcuts
		
		node item;
		
		foreach item debug_shortcuts (
		
			if (@item > 1) then (
				
				number_of_duplicate_shortcuts++;
				
				duplicate_shortcuts .= "-" . node_name(item) . " (" . @item . ")<br />";
			);
		);
		
		#
		#
		# Summary table
		#
		#
		
		'<table cellspacing="0">';
		
			'<tr>\n';
			'<th>Number of options:</th>';
			'<td>' . number_of_options . '</td>';
			'</tr>\n';
			
			'<tr>\n';
			'<th>Number of shortcuts:</th>';
			'<td>' . number_of_shortcuts . '</td>';
			'</tr>\n';
			
			'<tr>\n';
			'<th>Number of duplicate shortcuts:</th>';
			'<td>' . number_of_duplicate_shortcuts . '</td>';
			'</tr>\n';
			
			
			'<tr>\n';
			'<th>Duplicate shortcuts:</th>';
			'<td>' . duplicate_shortcuts . '</td>';
			'</tr>\n';
			
		'</table>';
		
		#
		#
		# Option detail tables
		#
		#
		
		html;
			
		'</body>\n';
		'</html>\n';
	)
	else (
	
		# No permission to view this resource (URL)
		display_no_permission_html();
	);
=}