{=

	#
	#
	# get_db_task_state.cfv (is called from client progress.js)
	#
	#

	include "templates.util.base_util";
	include "templates.util.database";
	include "templates.util.encoding";

	debug_message("\n\n\n#### get_db_task_state.cfv START \n");

	string session_id = volatile.session_id;
	string page_token = v.fp.page_token;
	
	if (get_is_valid_page_token(session_id, "progress", page_token)) then (
	
		string profile_name = internal.profile_name;
		string writing_task_id;
		bool is_active_task = false;
		
		#
		#
		# We check if the database is still active (building or updating)
		#
		#
		
		delete_node("v.database_info");
		get_database_info(profile_name, "v.database_info", false);
	
		node db_info_node = "v.database_info";
		
		debug_message("\n\n" . node_as_string(db_info_node) . "\n\n");
		
		
		if (db_info_node?{"writing_task_id"}) then (
		
			writing_task_id = @db_info_node{"writing_task_id"};
		);
		
		debug_message("#### writing_task_id: " . writing_task_id . "\n");
		
	
		if (writing_task_id ne "") then (
		
			delete_node("v.task_info");
			get_task_info("v.task_info");
			
			
			debug_message("\n\n" . node_as_string("v.task_info") . "\n\n");
	
			
			#
			# Check if the writing task exists and if it is active
			#
			
			node writing_task_node;
			
			if (?("v.task_info." . writing_task_id)) then (
			
				writing_task_node = "v.task_info." . writing_task_id;
				is_active_task = if (writing_task_node?{"active"} and @writing_task_node{"active"}) then (true) else (false);
			);
		);
		
		
		debug_message("\n#### is_active_task: " . is_active_task . "\n");
		
	
		string dat = "{";
		dat .= add_json("taskId", writing_task_id, "string");
		dat .= add_json("isActiveTask", is_active_task, "bool");
		dat = close_json(dat);
		
		"progress.getDbTaskStateResponse(" . dat . ")\n";
	)
	else (
	
		display_no_permission_html();
	);
		
	debug_message("\n\n\n#### get_db_task_state.cfv END \n");
=}