#
#
# build_html_overview()
#
#
# This builds the an overview html table element from the raw report element
# for standard overview and sessions_overview.
#
#

subroutine(build_html_overview(
	node raw_report_element,
	node html_formatting), (

	debug_message("\n\n#### build_html_overview() \n\n");
	
	bool is_date_time_support = @raw_report_element{"is_date_time_support"};
	
	string output_format = @html_formatting{"output_format"};
	bool is_dynamic_report = (output_format eq "dynamic");

	#
	# Add customize report element button if not sessions_overview
	#
	
	if (is_dynamic_report and
		(@raw_report_element{"report_element_type"} eq "overview") and
		@html_formatting{"permissions"}{"customize_report_element"}) then (
	
		string short_report_element_id = @raw_report_element{"short_report_element_id"};
	
		'<div class="standard-re-graphs-toolbar">';
		'<a id="' . short_report_element_id . ':customize:table" class="link-50" href="javascript:;" onclick="customizeRE.open(this)">';
		'<img src="' . fileref("picts/report/customize.gif") . '" width="16" height="16" alt="" />';
		'<span>' . lang_stats.btn.customize . '</span>';
		'</a>';
		'</div>';
	);
	
	'<div class="overview-re">\n';
	'<table class="overview-re" cellspacing="0">\n';
	
	#
	# header
	#
	
	'<tr>';
	
	if (is_date_time_support) then (
	
		'<th class="label">&nbsp;</th>';
		'<th>' . lang_stats.overview.all_days_label . '</th>';
		'<th class="last">' . lang_stats.overview.average_per_day_label . '</th>';
	
	)
	else (
		'<th class="label">&nbsp;</th>';
		'<th class="last">&nbsp;</th>';
	);
	
	'</tr>';
	
	#
	# rows
	#
	
	node row;
	node row_items = raw_report_element{"rows"};

	node column;
	int number_of_rows = num_subnodes(row_items);
	int row_count = 1;
	string label;
	string the_value;
	string display_format_type;
	string average_display_format_type;
	string average_per_day;
	int indent_level;
	
	string label_style;

	
	foreach row row_items (
	
		label = get_expanded_label(@row{"label"});
		display_format_type = @row{"display_format_type"};
		
		debug_message("\n####\n");
		
		debug_message("#### label: " . label . "\n");
		debug_message("#### display_format_type: " . display_format_type . "\n");
		
		the_value = @row{"the_value"};
		
		debug_message("#### the_value raw: " . the_value . "\n");
		
		the_value = format(the_value, display_format_type);
		
		debug_message("#### the_value formatted: " . the_value . "\n");
		
		indent_level = @row{"indent_level"};
	
		'<tr>';
		
		#
		# label
		#
		
		label_style = "";
		
		if (row_count == number_of_rows) then (
			label_style = "border-bottom-width:0;";
		);
		
		if (indent_level > 0) then (
			label_style .= "padding-left:" . (7 + (indent_level * 14)) . "px";
		);
		
		
		'<td class="label"';
		if (label_style ne "") then (
			' style="' . label_style . '"';
		);
		'>' . string_to_html(label) . '</td>';
		
		
		#
		# the value
		#
		
		'<td';
		if (!is_date_time_support) then (
			# Add classname for right border
			' class="last"';
		);
		if (row_count == number_of_rows) then (
			' style="border-bottom-width:0"';
		);
		'>' . the_value . '</td>';

		
		#
		# average per day
		#
		
		if (is_date_time_support) then (
		
			average_per_day = @row{"average_per_day"};
			
			debug_message("#### average_per_day raw value: " . average_per_day . "\n");
			
			if (average_per_day ne "-") then (
		
			average_display_format_type = @row{"average_display_format_type"};
				
				debug_message("#### average_display_format_type: " . average_display_format_type . "\n");
				
				average_per_day = format(average_per_day, average_display_format_type);
				
				debug_message("#### average_per_day formatted: " . average_per_day . "\n");
			);
		
			'<td class="last"';
			if (row_count == number_of_rows) then (
				' style="border-bottom-width:0"';
			);
			'>' . average_per_day . '</td>';
		);
	
		debug_message("####\n\n");
	
		'</tr>';
		
		row_count++;
	);
		
	'</table>\n';
	
	'</div>\n';
));