{=
  # TRANSLATORS: Translate the values in quotes on the next few lines, and do not translate the rest of the file
  string page_title = "All Options";
  string command_line_category = "Command Line Options";
  string preferences_category = "Preferences";
  string profile_category = "Profile Options";
  volatile.option_label_label = "Option name";
  volatile.option_name_label = "Command-line name";
  volatile.option_shortcut_label = "Command-line shortcut";
  volatile.option_short_description_label = "Description";

# NO TRANSLATION NEEDED BELOW THIS POINT

  include("util");
  start_docs_page(page_title);

subroutine(display_options(string thisnode, bool subtable), (
 
  debug_message("node: " . thisnode . "\n");
  # Add the header if this is the top
  if (!subtable) then (

    # Start the table
    "<table border=\"1\" cellspacing=\"0\">\n";

    # Add the header
    "<tr>\n";
    expand("<td><b>$volatile.option_label_label</b></td>\n");
    expand("<td><b>$volatile.option_short_description_label</b></td>\n");
#    "<td><b>$volatile.option_name_label</b></td>\n";
#    "<td><b>$volatile.option_shortcut_label</b></td>\n";
    "</tr>\n";

  ); # if subtable

  # Display all the subnodes
  string option_info_name;
  foreach option_info_name thisnode (

    # Get the name without options_info.
    string trimmed_option_name = remove_prefix(option_info_name, "option_info.");
    debug_message("trimmed_option_name: " . trimmed_option_name . "\n");

    # If this is a group, display it recursively
    if (!node_exists("lang_options." . trimmed_option_name . ".label") or
	node_exists("lang_options." . trimmed_option_name . ".option_group")) then (
      display_options(option_info_name, true);
    )

    # Otherwise, display this option
    else (

      # Compute the command line option name and the full option name
      string full_option_name = trimmed_option_name;
      string command_line_option_name = full_option_name;
      debug_message("full_option_name: " . full_option_name . "\n");
      if (starts_with(full_option_name, "profile.")) then (
        command_line_option_name = remove_prefix(full_option_name, "profile.");
        full_option_name = "default_profile." . command_line_option_name;
      );
      debug_message("full_option_name2: " . full_option_name . "\n");

      # Start the row
      "<tr>\n";

      # Add the label
      "<td>\n";
      string label_node = "lang_options." . trimmed_option_name . ".label";
      debug_message("label_node: " . label_node . "\n");
      if (node_exists(label_node)) then (
debug_message("Label exists in lang_options\n");
        docs_option_link(full_option_name);
      )
      else (
        "<font color=\"#ff0000\">no label</font>";
      );
      "</td>\n";

      # Add the short description
      "<td>\n";
      string short_description_node = "lang_options." . trimmed_option_name . ".short_description";
      if (node_exists(short_description_node)) then (
        expand($(short_description_node));
      )
      else (
        "<font color=\"#ff0000\">no short description</font>";
      );
      "<br>\n";

      # Start the command-line info
      "<font size=\"-1\">\n";

      # Add the node name
      "<br>\n";
      expand("$volatile.option_name_label:\n");
      expand("<code>$command_line_option_name</code>");

      # Add the shortcut
      string shortcut_node = "option_info." . trimmed_option_name . ".shortcut";
      if (node_exists(shortcut_node)) then (
        "<br>\n";
        expand("$volatile.option_shortcut_label:\n");
        "<code>" . $(shortcut_node) . "</code>";
      );

      # Finish the command line info
      "</font>\n";

      # Finish the description cell
      "</td>\n";

      # End the row
      "</tr>\n";

    ); # if not group

  ); # for options

  # End the table
  if (!subtable) then
    "</table>\n";

));

expand("<h2>$command_line_category</h2>\n");
display_options("option_info.command_line", false);

expand("<h2>$preferences_category</h2>\n");
display_options("option_info.preferences", false);

expand("<h2>$profile_category</h2>\n");
display_options("option_info.profile", false);

end_docs_page();

=}