{=
	#
	# miscellaneous save_data.cfv
	#
	
	include "templates.util.base_util";
	include "templates.util.rbac.rbac_util";
	include "templates.util.backup_util";
	include "templates.util.profiles.get_profile_data_util";
	
	string profile_name = internal.profile_name;
	string session_id = volatile.session_id;
	bool is_root_admin = get_is_root_admin();
	string page_token = v.fp.page_token;
	
	#
	# Check RBAC permissions
	#
	
	if ((is_root_admin or
		get_config_feature_permission(session_id, profile_name, "miscellaneous", "edit")) and
		get_is_valid_page_token(session_id, "miscellaneous", page_token)) then (
		
		debug_message("\n log miscellaneous _save\n" . node_as_string("v.fp") . "\n");

		string user_node_name = node_name(volatile.authenticated_user_node_path);

		string client_profiles_list_checksum = v.fp.profiles_list_checksum;

		# Get profiles checksum before the profile becomes saved!
		string profiles_list_checksum_before_profile_modification = get_profiles_list_checksum(session_id, is_root_admin, user_node_name);

		
		node profile = "profiles." . profile_name;
		
		node item;
		node network_node = profile{"network"};
		
		foreach item "v.fp.network" (
			set_subnode_value(network_node, node_name(item), @item);
		);
		
		# KHP 08/Aug/2013 - Changed save_node() to save_and_backup_profile()
		# save_node(profile);
		save_and_backup_profile(profile_name, profile);


		# Get profile_changes_dat, also in case of an error!
		string profile_changes_dat = get_profiles_list_data_after_profiles_changes(
			session_id,
			is_root_admin,
			user_node_name,
			client_profiles_list_checksum,
			profiles_list_checksum_before_profile_modification,
			profile_name,
			"save_profile");
		
		#
		# Response
		#

		string dat = "{";
		dat .= add_json("profileChanges", profile_changes_dat, "obj");
		dat = close_json(dat);
		
		"saveChangesResponse(" . dat . ")\n";
	)
	else (
	
		# No permission to access this resource (URL)
		display_no_permission_html();
	);
=}