$templates.shared.doctype
{= 
	include "templates.shared.util.encode_js";

	# ------------------------
	# check number of profiles
	# ------------------------
	
	# If no profile exist then don't allow to open the scheduler!
	
	int number_of_profiles = num_subnodes("profiles");

	# ----------------------------
	# Check scheduler default view
	# ----------------------------

	bool view_by_tasks = true;

	if (node_exists("preferences.miscellaneous.scheduler_view_by_tasks")) then (
		view_by_tasks = node_value("preferences.miscellaneous.scheduler_view_by_tasks");
	);

	# --------------------------
	# Subroutine build_view_node
	# --------------------------
	
	subroutine(build_view_node(bool view_by_tasks), (

		if (node_exists("volatile.temp.primary_fields")) then (
			delete_node("volatile.temp.primary_fields");
		);
	
		node item;
		
		string action_name;
		string action_label;
		string profile_name;
		string profile_label;
		string profile_position;
		string schedule_id;
		int field_id; # is equal number of subnodes in secondary_fields node
		string volatile_path;
	
		foreach item "schedule" (
			action_name = node_value(subnode_by_name(item, "action"));
	
				# For backward compatibility check for generate_all_report_files nodes!
				# generate_all_report_files become generate_report_files!
				if (action_name eq "generate_all_report_files") then (
					action_name = "generate_report_files";
				);
	
			action_label = node_value("lang_options.command_line." . action_name . ".label");
			profile_name = node_value(subnode_by_name(item, "profile"));
			schedule_id = node_name(item);
	
			if (profile_name eq "*") then (
				profile_name = "esc_all_profiles";
				profile_label = lang_admin.scheduler.all_profiles_label;
				profile_position = "0";
			)
			else (
				if (node_exists("profiles." . profile_name)) then (
					profile_label = node_value("profiles." . profile_name . ".label");
					
					if (contains(profile_label, "$")) then (profile_label = replace_all(profile_label, "$", "$"));
				)
				else (
					profile_label = profile_name;
					profile_name = "esc_no_profile_" . profile_name;			
				);
				profile_position = profile_label;
			);
	
			if (view_by_tasks) then (
	
				# ----------------
				# if view by tasks
				# ----------------
	
				if (!node_exists("volatile.temp.primary_fields." . action_name . "label")) then (
					"volatile.temp.primary_fields." . action_name . ".label" = action_label;
					"volatile.temp.primary_fields." . action_name . ".position" = action_label;	
				);
		
				if (!node_exists("volatile.temp.primary_fields." . action_name . ".secondary_fields")) then (
					field_id = 0;
				)
				else (
					field_id = num_subnodes("volatile.temp.primary_fields." . action_name . ".secondary_fields");
				);

				volatile_path = "volatile.temp.primary_fields." . action_name . ".secondary_fields." . field_id;

				volatile_path . ".schedule_id" = schedule_id;
				volatile_path . ".label" = profile_label;
				volatile_path . ".position" = profile_position;
			)
			else (
				# -------------------
				# if view by profiles
				# -------------------
	
				if (!node_exists("volatile.temp.primary_fields." . profile_name . "label")) then (
					"volatile.temp.primary_fields." . profile_name . ".label" = profile_label;
					"volatile.temp.primary_fields." . profile_name . ".position" = profile_position;
				);
	
				if (!node_exists("volatile.temp.primary_fields." . profile_name . ".secondary_fields")) then (
					field_id = 0;
				)
				else (
					field_id = num_subnodes("volatile.temp.primary_fields." . profile_name . ".secondary_fields");
				);

				volatile_path = "volatile.temp.primary_fields." . profile_name . ".secondary_fields." . field_id;
			
				volatile_path . ".schedule_id" = schedule_id;
				volatile_path . ".label" = action_label;
				volatile_path . ".position" = action_label;
			);
	
		); # foreach item
	
		# debug_message("NEW TEMP TASK NODE SORTED\n" . node_as_string("volatile.temp.primary_fields") . "\n");
	));

	# ------------------------------
	# Subroutine get_schedule_string
	# ------------------------------
	
	subroutine(get_schedule_string(string schedule_id), (

		node schedule = "schedule." . schedule_id;

		string month = node_value(subnode_by_name(schedule, "month"));
		string day;
		string day_of_month = node_value(subnode_by_name(schedule, "day_of_month"));
		string day_of_week = node_value(subnode_by_name(schedule, "day_of_week"));
		string hour = node_value(subnode_by_name(schedule, "hour"));
		string minute = node_value(subnode_by_name(schedule, "minute"));

		if (month eq "*") then (
			month = lang_admin.scheduler.any_month;
		)
		else (
			month = node_value("lang_stats.months." . month);
		);

		day = lang_admin.scheduler.any_day;

		if (day_of_month ne "*") then (
			day = lang_admin.scheduler.day . " " . day_of_month;
		);

		if (day_of_week ne "*") then (
			day =  node_value("lang_stats.weekdays." . day_of_week);
		);

		if (hour ne "*") then (
			if (length(hour) == 1) then (
				hour = "0" . hour;
			);
		)
		else (
			hour = lang_admin.scheduler.any_hour;
		);

		if (minute ne "*") then (
			if (length(minute) == 1) then (
				minute = "0" . minute;
			);
		)
		else (
			minute = lang_admin.scheduler.any_minute;
		);

		month . ", " . day . ", " . hour . ":" . minute;
	));

	
	# ---------------------------
	# Subroutine build_view_table
	# ---------------------------
	
	subroutine(build_view_table(bool view_by_tasks), (

		sort("volatile.temp.primary_fields", "field:position,alphabetical,ascending");

		# debug_message("NEW TEMP TASK NODE SORTED\n" . node_as_string("volatile.temp.primary_fields") . "\n");

		'<table class="task-primary-field" cellspacing="0">\n';

		node primary_field;
		string primary_field_name;
		string primary_field_label;

		foreach primary_field "volatile.temp.primary_fields" (

			primary_field_name = node_name(primary_field);
			primary_field_label = node_value(subnode_by_name(primary_field, "label"));

			'<tr>\n';
			'<td class="primary-field"><strong>' . primary_field_label . '</strong>';
			if (starts_with(primary_field_name, "esc_no_profile")) then (
				' <span style="color:Red">[ ' . lang_admin.scheduler.profile_does_not_exist_info . ' ]</span>';
			);
			'</td>\n';
			'</tr>\n';

			node secondary_field;
			node secondary_fields_node = primary_field . ".secondary_fields";
			string secondary_field_label;
			string schedule_id;
			string action_name;
			string profile_name;
			string report_name;
			string report_label;
			string recipient_email_address;
			string generate_html_to_directory;
			bool generate_pdf_friendly_files;
			string remove_database_data_filter;
			string number_of_days;
			string extra_options;

			string delete_label;

			# Sort the secondary field
			sort(secondary_fields_node, "field:position,alphabetical,ascending");

			foreach secondary_field secondary_fields_node (
				secondary_field_label = node_value(subnode_by_name(secondary_field, "label"));
				schedule_id = node_value(subnode_by_name(secondary_field, "schedule_id"));
				profile_name = node_value("schedule." . schedule_id . ".profile");
				action_name = node_value("schedule." . schedule_id . ".action");

				# delete_label = replace_all(primary_field_label, "'", "\'") . ", " . replace_all(secondary_field_label, "'", "\'");
				delete_label = encode_js(primary_field_label) . ", " . encode_js(secondary_field_label);

				
				'<tr>\n';
				'<td>\n';
					'<table class="task-secondary-field" cellspacing="0">\n';
					'<tr>\n';
					'<td style="width:30px">&nbsp;</td>\n';
					'<td>';
					expand(`<a href="javascript:;" onclick="open_schedule_form('edit', '$schedule_id');">`);
					'<strong>' . secondary_field_label . '</strong></a>';
					if (view_by_tasks and
						(profile_name ne "*") and
						(!node_exists("profiles." . profile_name))) then (
						' <span style="color:Red">[ ' . lang_admin.scheduler.profile_does_not_exist_info . ' ]</span>';
					);
					'</td>\n';
					'<td style="text-align:right">';
					expand(`<a href="javascript:;" onclick="open_schedule_form('edit', '$schedule_id');">$lang_admin.general.edit_button</a> | `);
					expand(`<a href="javascript:;" onclick="delete_schedule('$schedule_id', '$delete_label')">$lang_admin.general.delete_button</a>\n`);
					'</td>\n';
					'</tr>\n';
					'</table>\n';
				'</td>\n';
				'</tr>\n';


				'<tr>\n';
				'<td class="details-border">\n';

					'<table class="task-details" cellspacing="0">\n';

					if ((node_exists("schedule." . schedule_id . ".options.rn")) or
						(action_name eq "generate_all_report_files")) then (

						if (node_exists("schedule." . schedule_id . ".options.rn")) then (
								report_name = node_value("schedule." . schedule_id . ".options.rn");

								if (report_name ne "*") then (
									
									if (node_exists("profiles." . profile_name . ".statistics.reports." . report_name)) then (

										set_active_profile(profile_name);

										report_label = expand(node_value("profiles." . profile_name . ".statistics.reports." . report_name . ".label"));
									)
									else (
										report_label = report_name . "-";
									);
								)
								else (
									report_label = lang_admin.scheduler.all_reports_label;
								);
						)
						else (
							# for backwards compatibility only, action is "generate_all_report_files" which
							# has been replaced by "generate_report_files", -rn * (star is equal all reports)

							report_label = lang_admin.scheduler.all_reports_label;
						);

						'<tr>\n';
						'<td style="width:60px">&nbsp;</td>\n';
						'<td class="label">' . lang_admin.scheduler.report_label . ':</td>\n';
						'<td>' . report_label . '</td>\n';
						'</tr>\n';
					);

					if (node_exists("schedule." . schedule_id . ".options.rca")) then (
						recipient_email_address = node_value("schedule." . schedule_id . ".options.rca");

						'<tr>\n';
						'<td style="width:60px">&nbsp;</td>\n';
						'<td class="label">' . lang_admin.scheduler.recipient_email_address_short_label . ':</td>\n';
						'<td>' . recipient_email_address . '</td>\n';
						'</tr>\n';
					);

					if (node_exists("schedule." . schedule_id . ".options.ghtd")) then (
						generate_html_to_directory = node_value("schedule." . schedule_id . ".options.ghtd");

						'<tr>\n';
						'<td style="width:60px">&nbsp;</td>\n';
						'<td class="label">' . capitalize(expand(lang_stats.directory)) . ':</td>\n';
						'<td>' . generate_html_to_directory . '</td>\n';
						'</tr>\n';
					);
					
					if (node_exists("schedule." . schedule_id . ".options.gpff") and
						node_exists("lang_admin.scheduler.generate_pdf_friendly_files_label")) then (
						generate_pdf_friendly_files = node_value("schedule." . schedule_id . ".options.gpff");

						'<tr>\n';
						'<td style="width:60px">&nbsp;</td>\n';
						'<td class="label">&nbsp;</td>\n';
						'<td>';
						'<input type="checkbox" disabled="disabled"';
						if (generate_pdf_friendly_files) then (' checked="checked"');
						' /> ' . lang_admin.scheduler.generate_pdf_friendly_files_label . '</td>\n';
						'</tr>\n';
					);

					if ((action_name eq "remove_database_data") and (node_exists("schedule." . schedule_id . ".options.f"))) then (

						if (!node_value("schedule." . schedule_id . ".filter.custom_expression")) then (
							number_of_days = node_value("schedule." . schedule_id . ".filter.number_of_days");
							string param1 = number_of_days;
							remove_database_data_filter = expand(lang_admin.scheduler.remove_database_data_older_than_n_days_info);
						)
						else (
							remove_database_data_filter = node_value("schedule." . schedule_id . ".options.f");
						);
	
						'<tr>\n';
						'<td style="width:60px">&nbsp;</td>\n';
						'<td class="label">' . lang_admin.scheduler.filter_label . ':</td>\n';
						'<td>' . remove_database_data_filter . '</td>\n';
						'</tr>\n';
					);	

					if (node_exists("schedule." . schedule_id . ".extra_options")) then (
						extra_options = node_value("schedule." . schedule_id . ".extra_options");
						if (extra_options ne "") then (
							'<tr>\n';
							'<td style="width:60px">&nbsp;</td>\n';
							'<td class="label">' . lang_admin.scheduler.extra_options_label . ':</td>\n';
							'<td>' . extra_options . '</td>\n';
							'</tr>\n';
						);
					);

					'<tr>\n';
					'<td style="width:60px">&nbsp;</td>\n';
					'<td class="label">' . lang_admin.scheduler.schedule_label . ':</td>\n';
					'<td>' . get_schedule_string(schedule_id) . '</td>\n';
					'</tr>\n';

					'</table>\n';
				'</td>\n';
				'</tr>\n';

			); # foreach secondary_field

		); # foreach primary_field;

		'</table>\n';
	));

=}
<html>
<head>
<title></title>
{= expand(templates.shared.content_type); =}
<link href={=fileref("css/admin_config.css")=} rel="stylesheet" type="text/css" />

<script language="JavaScript" src={=fileref("js/util.js")=}></script>
<script language="JavaScript" type="text/JavaScript">

var _user_name;
var _number_of_profiles = $number_of_profiles;
var _no_profile_exists_msg = '$lang_admin.scheduler.no_profile_exists_message';

window.onload = init_onload;

function init_onload(){

}

function set_scheduler_view(view_by_tasks) {
	var view_by_tasks_section = document.getElementById('view_by_tasks_section');
	var view_by_tasks_label = document.getElementById('view_by_tasks_label');
	var view_by_profiles_section = document.getElementById('view_by_profiles_section');
	var view_by_profiles_label = document.getElementById('view_by_profiles_label');

	if (view_by_tasks) {
		view_by_profiles_section.style.display = 'none';
		view_by_profiles_label.style.display = 'none';
		view_by_tasks_section.style.display = 'block';
		view_by_tasks_label.style.display = 'block';
	}
	else {
		view_by_tasks_section.style.display = 'none';
		view_by_tasks_label.style.display = 'none';
		view_by_profiles_section.style.display = 'block';
		view_by_profiles_label.style.display = 'block';
	}

	var url = '?dp+templates.admin.scheduler.set_scheduler_default_view+volatile.view_by_tasks+' + view_by_tasks;
	return call_to_server(url);
}

function open_schedule_form(form_type, schedule_id) {

	if (_number_of_profiles > 1) {
	
		var width = 770;
		var height = 555;
		var window_name = 'scheduler_form';
	
		var url = '?dp+templates.admin.scheduler.scheduler_form';
	
		if (form_type == 'new') {
			url += '+volatile.form_type+new';
		}
		else {
			url += '+volatile.form_type+edit';
			url += '+volatile.schedule_id+' + schedule_id;
		}
		
		open_form_window(url, window_name, width, height);
	}
	else {
	
		alert(_no_profile_exists_msg);
	}
}

function delete_schedule(schedule_id, delete_label) {

	{= string param1 = "_PARAM1_"; =}
	var msg = '$lang_admin.scheduler.confirm_delete_message';
	msg = msg.replace(/_PARAM1_/, delete_label);
	
	var url = '?dp+templates.admin.scheduler.delete_schedule';
	url += '+volatile.schedule_id+' + schedule_id;
	

	if (confirm(msg)) {
		document.getElementById('content').style.display = 'none';
		document.getElementById('info_delete').style.display = 'block';
		return call_to_server(url);
	}
	
	return false;
}

function server_response_delete_schedule() {
	location.reload(true);
}

</script>

<style type="text/css">

</style>

</head>

<body>

<div id="content" class="content">

<table class="header-bar" cellspacing="0">
<tr>
<td class="header-title">$lang_admin.scheduler.label</td>
<td class="right">
<a href="javascript:;" onclick="open_schedule_form('new')">$lang_admin.scheduler.new_action_button</a>
</td>
</tr>
</table>

{=
	bool tasks_exists = false;

	if (node_exists("schedule")) then (
		if (num_subnodes("schedule") >= 1) then (
			tasks_exists = true;
		);
	);
	
	if (tasks_exists) then (

		# ---------------------
		# Scheduler view switch
		# ---------------------

		'<table class="scheduler-view-switch" cellspacing="0">\n';
		'<tr>\n';
	
		'<td>';
			'<span id="view_by_tasks_label"';
			if (!view_by_tasks) then (' style="display:none"');
			'><strong>' . lang_admin.scheduler.actions_profiles_label . '</strong></span>';
	
			'<span id="view_by_profiles_label"';
			if (view_by_tasks) then (' style="display:none"');
			'><strong>' . lang_admin.scheduler.profiles_actions_label . '</strong></span>';
		'</td>\n';
	
		'<td style="text-align:right;">\n';
			'<form name="scheduler_view_switch_form" onsubmit="return false" style="margin:0px;">\n';
		
			'<input type="radio" id="view_by_tasks" name="scheduler_view_switch"';
			if (view_by_tasks) then (' checked="checked"');
			' onclick="set_scheduler_view(true)" />\n';
			' <label for="view_by_tasks">' . lang_admin.scheduler.view_by_actions_button . '</label>\n';
			'&nbsp;&nbsp;';
			'<input type="radio" id="view_by_profiles" name="scheduler_view_switch"';
			if (!view_by_tasks) then (' checked="checked"');
			' onclick="set_scheduler_view(false)" />\n';
			' <label for="view_by_profiles">' . lang_admin.scheduler.view_by_profiles_button . '</label>\n';
		
			'</form>\n';
		'</td>\n';
	
		'</tr>\n';
		'</table>\n';

		# --------------------
		# Tasks/Profiles table
		# --------------------

		'<div id="view_by_tasks_section"';
		if (!view_by_tasks) then (' style="display:none"');
		'>\n';

		build_view_node(true);
		build_view_table(true);

		'</div>\n';

		# --------------------
		# Profiles/Tasks table
		# --------------------

		'<div id="view_by_profiles_section"';
		if (view_by_tasks) then (' style="display:none"');
		'>\n';

		build_view_node(false);
		build_view_table(false);

		'</div>\n';
	)
	else (
		
		# -------------------
		# No task in schedule
		# -------------------

		'<p style="padding-left:9px">' . lang_admin.scheduler.no_actions_defined_info . '</p>\n';
	);
	
expand(templates.shared.copyright);
'</div> <!-- content -->\n';

=}

<div id="info_delete" style="display:none;">
<h4 class="action-info-no-padding">$lang_admin.scheduler.deleting_info</h4>
</div>

</body>
</html>